plugins {
    id 'multiloader-loader'
    id 'fabric-loom'
}
dependencies {
    minecraft "com.mojang:minecraft:${minecraft_version}"
    mappings loom.layered {
        officialMojangMappings()
        parchment("org.parchmentmc.data:parchment-${parchment_minecraft}:${parchment_version}@zip")
    }
    modImplementation "net.fabricmc:fabric-loader:${fabric_loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${fabric_version}"

    modImplementation include("org.spongepowered:configurate-core:${project.configurate_version}")
    modImplementation include("org.spongepowered:configurate-hocon:${project.configurate_version}")
    modImplementation include("org.spongepowered:configurate-gson:${project.configurate_version}")
    include("com.typesafe:config:1.4.3")
    include("io.leangen.geantyref:geantyref:1.3.16")

    // Mod dependencies

    include modImplementation("me.lucko:fabric-permissions-api:${project.permissions_api_version}")

    include modImplementation("eu.pb4:placeholder-api:${project.placeholderapi_version}")
    include modImplementation("eu.pb4:sgui:${project.sgui_version}")

    modCompileOnly "dev.emi:trinkets:${project.trinkets_version}"
    modRuntimeOnly "dev.emi:trinkets:${project.trinkets_version}"

    modCompileOnly "net.luckperms:api:5.4"
    modRuntimeOnly "net.luckperms:api:5.4"
}

loom {
    def aw = project(':common').file("src/main/resources/${mod_id}.accesswidener")
    if (aw.exists()) {
        accessWidenerPath.set(aw)
    }
    mixin {
        defaultRefmapName.set("${mod_id}.refmap.json")
    }
    runs {
        server {
            server()
            setConfigName('Fabric Server')
            ideConfigGenerated(true)
            runDir('runs/server')
        }
    }
}